Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Documentation GitHub

use std/io

func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/fmt.Format
use std/io

struct Point {
    x: i32
    y: i32
}

instance Point {
    impl Format
    method &self.try_format_into(output: &+String): void! {
        output.try_push_str("(")?
        self.x.try_format_into(output)?
        output.try_push_str(", ")?
        self.y.try_format_into(output)?
        output.try_push_str(")")?
        return
    }
}

func main(): i32! {
    let point = Point { x: 3, y: 4 }
    let message = "point = ${point}\n"
    io.print(&message)?
    return 0
}

use std/io
use std/vec.Vec

struct Point {
    x: i32
    y: i32
}

instance Point {
    operator (&self == other: &Self): bool {
        return self.x == other.x && self.y == other.y
    }
}

func main(): i32! {
    let first = Point { x: 3, y: 4 }
    let same = Point { x: 3, y: 4 }
    let other = Point { x: 5, y: 6 }
    if first != same || first == other {
        return 1
    }
    let points = Vec [move first, move other]
    if points[0] != same {
        return 1
    }
    var values = Vec [1, 2, 3]
    values[1] = 4
    if values[0] + values[1] + values[2] != 8 {
        return 1
    }
    io.print("equality found the point\n")?
    return 0
}

struct Buffer {
    values: [i32; 3]
}

instance Buffer {
    operator (&self[index: usize]): &i32 {
        return &self.values[index]
    }

    operator (&+self[index: usize]): &+i32 {
        return &+self.values[index]
    }
}

func at<C>(container: &C, index: usize): i32 where (&C[usize]): &i32 {
    return container[index]
}

func main(): i32 {
    var buffer = Buffer { values: [3, 4, 5] }
    buffer[1] = 9
    if at(&buffer, 1) != 9 {
        return 1
    }
    return 0
}

/development/std/char/scalar.nct

scalar.nct

//! Unicode scalar construction, observation, and ordering.

see ./index.nct

use /internal/character
use /internal/ptr

construct char {
    noalloc func from_u32(value: u32): Self? {
        if value > 1114111 { return none }
        if value >= 55296 && value <= 57343 { return none }
        return character.char_from_u32_unchecked(value)
    }
}

instance char {
    noalloc method self.code_point(): u32 {
        return character.char_code_point_raw(self)
    }

    noalloc method self.utf8_len(): usize {
        let value = self.code_point()
        if value <= 127 { return 1 }
        if value <= 2047 { return 2 }
        if value <= 65535 { return 3 }
        return 4
    }

    noalloc method self.is_ascii(): bool {
        return self.code_point() <= 127
    }

    noalloc method self.is_ascii_digit(): bool {
        let value = self.code_point()
        return value >= 48 && value <= 57
    }

    noalloc operator (&self == other: &Self): bool {
        return character.char_code_point_raw(ptr.copy_value(self))
            == character.char_code_point_raw(ptr.copy_value(other))
    }

    noalloc operator (&self < other: &Self): bool {
        return character.char_code_point_raw(ptr.copy_value(self))
            < character.char_code_point_raw(ptr.copy_value(other))
    }
}