Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Documentation GitHub

use std/io

func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/fmt.Format
use std/io

struct Point {
    x: i32
    y: i32
}

instance Point {
    impl Format
    method &self.format_into(output: &+String): void {
        output.push_str("(")
        self.x.format_into(output)
        output.push_str(", ")
        self.y.format_into(output)
        output.push_str(")")
        return
    }
}

func main(): i32! {
    let point = Point { x: 3, y: 4 }
    let message = "point = ${point}\n"
    io.print(&message)?
    return 0
}

use std/io
use std/vec.Vec

struct Point {
    x: i32
    y: i32
}

instance Point {
    operator (&self == other: &Self): bool {
        return self.x == other.x && self.y == other.y
    }
}

func main(): i32! {
    let first = Point { x: 3, y: 4 }
    let same = Point { x: 3, y: 4 }
    let other = Point { x: 5, y: 6 }
    if first != same || first == other {
        return 1
    }
    let points = Vec [move first, move other]
    if points[0] != same {
        return 1
    }
    var values = Vec [1, 2, 3]
    values[1] = 4
    if values[0] + values[1] + values[2] != 8 {
        return 1
    }
    io.print("equality found the point\n")?
    return 0
}

struct Buffer {
    values: [i32; 3]
}

instance Buffer {
    operator (&self[index: usize]): &i32 {
        return &self.values[index]
    }

    operator (&+self[index: usize]): &+i32 {
        return &+self.values[index]
    }
}

func at<C>(container: &C, index: usize): i32 where (&C[usize]): &i32 {
    return container[index]
}

func main(): i32 {
    var buffer = Buffer { values: [3, 4, 5] }
    buffer[1] = 9
    if at(&buffer, 1) != 9 {
        return 1
    }
    return 0
}

/development/std/fs/directory_mutation.nct

directory_mutation.nct

//! Public directory lifecycle policy over one target mutation attempt.

see ./index.nct
see ./darwin.nct

use /internal/io
use /internal/os.OSErrorKind
use /path as path_module

func create_dir(path: &str): void! {
    let attempt = create_directory_target(path)?
    if attempt is CreateDirectoryAttempt.already_exists {
        return io.io_error_from_kind(OSErrorKind.already_exists)
    }
    return
}

func create_dir_all(path: &str): void! {
    path_module.validate(path)?
    if path.len() == 0 {
        return io.io_error_from_kind(OSErrorKind.invalid_input)
    }

    var end: usize = 0
    while end < path.len() {
        while end < path.len() && path[end] == 47 {
            end += 1
        }
        if end == path.len() { return }
        while end < path.len() && path[end] != 47 {
            end += 1
        }

        let prefix = path.get_range(0, end) otherwise {
            return error.new(
                "std.fs.internal_path_boundary",
                "directory prefix did not end at a UTF-8 boundary",
            )
        }
        ensure_directory(prefix)?
    }
    return
}

func ensure_directory(value: &str): void! {
    let attempt = create_directory_target(value)?
    if attempt is CreateDirectoryAttempt.created { return }
    if existing_path_is_directory_target(value)? { return }
    return io.io_error_from_kind(OSErrorKind.not_directory)
}

func remove_dir(path: &str): void! {
    remove_directory_target(path)?
    return
}