Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Documentation GitHub

use std/io

func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/fmt.Format
use std/io

struct Point {
    x: i32
    y: i32
}

instance Point {
    impl Format
    method &self.try_format_into(output: &+String): void! {
        output.try_push_str("(")?
        self.x.try_format_into(output)?
        output.try_push_str(", ")?
        self.y.try_format_into(output)?
        output.try_push_str(")")?
        return
    }
}

func main(): i32! {
    let point = Point { x: 3, y: 4 }
    let message = "point = ${point}\n"
    io.print(&message)?
    return 0
}

use std/io
use std/vec.Vec

struct Point {
    x: i32
    y: i32
}

instance Point {
    operator (&self == other: &Self): bool {
        return self.x == other.x && self.y == other.y
    }
}

func main(): i32! {
    let first = Point { x: 3, y: 4 }
    let same = Point { x: 3, y: 4 }
    let other = Point { x: 5, y: 6 }
    if first != same || first == other {
        return 1
    }
    let points = Vec [move first, move other]
    if points[0] != same {
        return 1
    }
    var values = Vec [1, 2, 3]
    values[1] = 4
    if values[0] + values[1] + values[2] != 8 {
        return 1
    }
    io.print("equality found the point\n")?
    return 0
}

struct Buffer {
    values: [i32; 3]
}

instance Buffer {
    operator (&self[index: usize]): &i32 {
        return &self.values[index]
    }

    operator (&+self[index: usize]): &+i32 {
        return &+self.values[index]
    }
}

func at<C>(container: &C, index: usize): i32 where (&C[usize]): &i32 {
    return container[index]
}

func main(): i32 {
    var buffer = Buffer { values: [3, 4, 5] }
    buffer[1] = 9
    if at(&buffer, 1) != 9 {
        return 1
    }
    return 0
}

/development/std/str/casing_tests.nct

casing_tests.nct

//! Unicode default case-conversion contract tests.

see ./index.nct

use /mem

test default_casing_handles_full_and_contextual_mappings {
    let dotted_i = "İ".to_lowercase()
    if (&dotted_i as &str) != "i\xCC\x87" {
        return error.new("std.str.test", "full lowercase mapping changed")
    }

    let sharp_s = "ß".to_uppercase()
    if (&sharp_s as &str) != "SS" {
        return error.new("std.str.test", "full uppercase mapping changed")
    }

    let final_sigma = "ΟΣ".to_lowercase()
    let medial_sigma = "ΟΣΑ".to_lowercase()
    if (&final_sigma as &str) != "ος" || (&medial_sigma as &str) != "οσα" {
        return error.new("std.str.test", "Final_Sigma context changed")
    }

    let ignored_before = "Ο\xCC\x81Σ".to_lowercase()
    let ignored_after = "ΟΣ\xCC\x81".to_lowercase()
    if (&ignored_before as &str) != "ο\xCC\x81ς"
        || (&ignored_after as &str) != "ος\xCC\x81" {
        return error.new("std.str.test", "case-ignorable context changed")
    }
    return
}

test recoverable_casing_uses_the_selected_allocator {
    var allocator = mem.page_try_allocator()
    let lower = "İΣ".try_to_lowercase(&+allocator)?
    let upper = "ﬃß".try_to_uppercase(&+allocator)?
    if (&lower as &str) != "i\xCC\x87ς" || (&upper as &str) != "FFISS" {
        return error.new("std.str.test", "recoverable default casing changed")
    }
    return
}