Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Specification GitHub

use std/io

blocking func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

use std/io
use std/vec.Vec

struct Counter {
    value: i32
}

blocking func main(): i32! {
    var counters = Vec [Counter { value: 1 }, Counter { value: 2 }, Counter { value: 3 }]
    for counter in &+counters {
        counter.value += 10
    }

    var borrowed_total: i32 = 0
    for counter in &counters {
        borrowed_total += counter.value
    }

    var moved_total: i32 = 0
    for counter in move counters {
        moved_total += counter.value
    }

    let message = "borrowed: ${borrowed_total}, moved: ${moved_total}\n"
    io.print(&message)?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/task
use std/time
use std/time.Duration

async func delayed(value: i32): i32 {
    await time.sleep(Duration.from_milliseconds(1))
    return value
}

async func main(): i32! {
    let (left, right) = await task.join(delayed(20), delayed(22))
    if left + right != 42 {
        return error.new("example.unexpected_total", "joined tasks returned the wrong total")
    }
    return 0
}

use std/io
use std/url.Url

blocking func main(): i32! {
    let url = Url.parse("HTTP://Example.COM:80/a/../status?q=ready#fragment")?
    let canonical = url.to_string()
    let authority = url.authority()
    let target = url.request_target()
    io.println(&canonical)?
    io.println(&authority)?
    io.println(&target)?
    return 0
}

limits.nct

see ./index.nct

see ./storage.nct

const STANDARD_INPUT_BYTES: usize = 67108864

const STANDARD_OUTPUT_BYTES: u64 = 268435456

const STANDARD_ENTRIES: usize = 4096

const STANDARD_PATH_BYTES: usize = 240

noalloc func invalid_limits(): error {
    return error.new("archive-inspect.invalid_limits", "every archive limit must be nonzero")
}

construct ArchiveLimits {
    noalloc func standard(): Self {
        return ArchiveLimits {
            input_bytes: STANDARD_INPUT_BYTES,
            decoded_bytes: STANDARD_OUTPUT_BYTES,
            entries: STANDARD_ENTRIES,
            path_bytes: STANDARD_PATH_BYTES,
        }
    }

    noalloc func new(
        maximum_input_bytes: usize,
        maximum_decoded_bytes: u64,
        maximum_entries: usize,
        maximum_path_bytes: usize,
    ): Self! {
        if maximum_input_bytes == 0 || maximum_decoded_bytes == 0
        || maximum_entries == 0 || maximum_path_bytes == 0 {
            return invalid_limits()
        }
        return ArchiveLimits {
            input_bytes: maximum_input_bytes,
            decoded_bytes: maximum_decoded_bytes,
            entries: maximum_entries,
            path_bytes: maximum_path_bytes,
        }
    }
}