Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Specification GitHub

use std/io

blocking func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/fmt.Format
use std/io

struct Point {
    x: i32
    y: i32
}

instance Point {
    impl Format
    method &self.try_format_into(output: &+String): void! {
        output.try_push_str("(")?
        self.x.try_format_into(output)?
        output.try_push_str(", ")?
        self.y.try_format_into(output)?
        output.try_push_str(")")?
        return
    }
}

blocking func main(): i32! {
    let point = Point { x: 3, y: 4 }
    let message = "point = ${point}\n"
    io.print(&message)?
    return 0
}

use std/io
use std/vec.Vec

struct Point {
    x: i32
    y: i32
}

instance Point {
    operator (&self == other: &Self): bool {
        return self.x == other.x && self.y == other.y
    }
}

blocking func main(): i32! {
    let first = Point { x: 3, y: 4 }
    let same = Point { x: 3, y: 4 }
    let other = Point { x: 5, y: 6 }
    if first != same || first == other {
        return 1
    }
    let points = Vec [move first, move other]
    if points[0] != same {
        return 1
    }
    var values = Vec [1, 2, 3]
    values[1] = 4
    if values[0] + values[1] + values[2] != 8 {
        return 1
    }
    io.print("equality found the point\n")?
    return 0
}

struct Buffer {
    values: [i32; 3]
}

instance Buffer {
    operator (&self[index: usize]): &i32 {
        return &self.values[index]
    }

    operator (&+self[index: usize]): &+i32 {
        return &+self.values[index]
    }
}

func at<C>(container: &C, index: usize): i32 where (&C[usize]): &i32 {
    return container[index]
}

func main(): i32 {
    var buffer = Buffer { values: [3, 4, 5] }
    buffer[1] = 9
    if at(&buffer, 1) != 9 {
        return 1
    }
    return 0
}

/examples/async-udp/exchange.nct

exchange.nct

see ./index.nct

use std/net.{IpAddress, Ipv4Address, SocketAddress, UdpSocket}
use std/time.Duration
use std/vec.Vec

noalloc func loopback(): SocketAddress {
    return SocketAddress.new(IpAddress.from_ipv4(Ipv4Address.loopback()), 0)
}

async func run(): i32! {
    let timeout = Duration.from_seconds(1)
    var sender = UdpSocket.bind(loopback())?
    var receiver = UdpSocket.bind(loopback())?
    let sender_address = sender.local_address()?
    let receiver_address = receiver.local_address()?

    await sender.send_to_with_timeout("ping".bytes(), receiver_address, timeout)?
    var bytes: Vec<u8> = Vec [
        u8.truncate(0),
        u8.truncate(0),
        u8.truncate(0),
        u8.truncate(0),
    ]
    let received = await receiver.receive_with_timeout(&+bytes, timeout)?
    if received.source() != sender_address || received.copied_len() != 4
    || received.was_truncated() || bytes[0] != 112 || bytes[1] != 105
    || bytes[2] != 110 || bytes[3] != 103 {
        return error.new("async-udp.datagram", "UDP changed one message boundary")
    }

    sender.connect(receiver_address)?
    receiver.connect(sender_address)?
    await receiver.send("pong".bytes())?
    let reply = await sender.receive_with_timeout(&+bytes, timeout)?
    if reply.copied_len() != 4 || reply.was_truncated()
    || bytes[0] != 112 || bytes[1] != 111 || bytes[2] != 110 || bytes[3] != 103 {
        return error.new("async-udp.reply", "connected UDP changed one reply")
    }
    return 0
}