Programming Language

Nocter

A self-contained systems language built around simplicity, encapsulation, and foolproof design.

Specification GitHub

use std/io

blocking func main(): i32! {
    io.print("Hello from Nocter\n")?
    return 0
}

func main(): i32 {
    let value = load_value() catch failure { fallback_for(failure.message()) }
    if value == 42 {
        return 0
    }
    return 1
}

func load_value(): i32! {
    return error.new("example.unavailable", "the primary value is unavailable")
}

func fallback_for(message: &str): i32 {
    return 42
}

use std/fmt.Format
use std/io

struct Point {
    x: i32
    y: i32
}

instance Point {
    impl Format
    method &self.try_format_into(output: &+String): void! {
        output.try_push_str("(")?
        self.x.try_format_into(output)?
        output.try_push_str(", ")?
        self.y.try_format_into(output)?
        output.try_push_str(")")?
        return
    }
}

blocking func main(): i32! {
    let point = Point { x: 3, y: 4 }
    let message = "point = ${point}\n"
    io.print(&message)?
    return 0
}

use std/io
use std/vec.Vec

struct Point {
    x: i32
    y: i32
}

instance Point {
    operator (&self == other: &Self): bool {
        return self.x == other.x && self.y == other.y
    }
}

blocking func main(): i32! {
    let first = Point { x: 3, y: 4 }
    let same = Point { x: 3, y: 4 }
    let other = Point { x: 5, y: 6 }
    if first != same || first == other {
        return 1
    }
    let points = Vec [move first, move other]
    if points[0] != same {
        return 1
    }
    var values = Vec [1, 2, 3]
    values[1] = 4
    if values[0] + values[1] + values[2] != 8 {
        return 1
    }
    io.print("equality found the point\n")?
    return 0
}

struct Buffer {
    values: [i32; 3]
}

instance Buffer {
    operator (&self[index: usize]): &i32 {
        return &self.values[index]
    }

    operator (&+self[index: usize]): &+i32 {
        return &+self.values[index]
    }
}

func at<C>(container: &C, index: usize): i32 where (&C[usize]): &i32 {
    return container[index]
}

func main(): i32 {
    var buffer = Buffer { values: [3, 4, 5] }
    buffer[1] = 9
    if at(&buffer, 1) != 9 {
        return 1
    }
    return 0
}

/examples/binary-record/streams.nct

streams.nct

see ./index.nct

use std/io.{BlockingReader, Reader}

struct FragmentedBytes {
    input: &[u8]
    next_offset: usize
    maximum_chunk: usize
}

construct FragmentedBytes {
    noalloc func new(input: &[u8], maximum_chunk: usize): Self from input {
        return FragmentedBytes {
            input: input,
            next_offset: 0,
            maximum_chunk: if maximum_chunk == 0 { 1 } else { maximum_chunk },
        }
    }
}

noalloc func read_fragment(source: &+FragmentedBytes, destination: &+[u8]): usize {
    let remaining = source.input.len() - source.next_offset
    var count = destination.len()
    if count > source.maximum_chunk { count = source.maximum_chunk }
    if count > remaining { count = remaining }
    var index: usize = 0
    while index < count {
        destination[index] = source.input[source.next_offset + index]
        index += 1
    }
    source.next_offset += count
    return count
}

instance FragmentedBytes {
    blocking method &+self.read_blocking(buffer: &+[u8]): usize! {
        return read_fragment(self, buffer)
    }

    async method &+self.read(buffer: &+[u8]): usize! {
        return read_fragment(self, buffer)
    }
}

blocking func decode_blocking<R>(reader: &+R): RecordLog! where R impl BlockingReader {
    let input = reader.read_to_end_blocking()?
    return decode_log(&input as &[u8])?
}

async func decode_async<R>(reader: &+R): RecordLog! where R impl Reader {
    let input = await reader.read_to_end()?
    return decode_log(&input as &[u8])?
}